(import-macros {: map} :lib.macro)

(local peg
 (if (pick-values 1 (pcall require :lpeg))
   (require :lpeg)
   (require :lpeglj)))
(local parser (require :parser.parser))
(local number (require :lib.number))
(local fetcher (require :fetcher))

(fn format-url [path page]
  (.. "https://artoftea.ru/" path "/?page=" page))

(local product-peg
  (* ;; id
    (parser.anywhere
     (parser.tag :div {:class "front-image"}
      (parser.tag :a {:href (peg.Cg (parser.till "\"") :url)}
       (parser.tag :img {:src (peg.Cg (parser.till "\"") :image)
                         :title "*" :class "*" :alt "*"}))))
    (parser.anywhere
     (parser.tag :div {:class "name"}
      (parser.tag :a {:href "*"} (peg.Cg (parser.till "</a>") :title))))
    (parser.anywhere
     (parser.tag :p {:class "description"}
      (peg.Cg (parser.till "</p>") :description)))
    (+
      (*
        (parser.anywhere
         (parser.tag :option {:value "*" :selected "selected"}
           (* (peg.Cg parser.pegs.number :weight) " гр" parser.pegs.spaces)))
        (parser.anywhere
         (parser.tag :p {:class "price"}
           (parser.tag :span {:id "*"}
           (peg.Cg (parser.till "</span>") :price)))))
      (parser.anywhere
       (parser.tag :p {:class "price"}
        (parser.tag :span {:id "*"}
        (peg.Cg (parser.till "</span>") :price)))))
    (parser.anywhere
     (parser.tag :input {:type "hidden"
                         :name "product_id"
                         :value (peg.Cg parser.pegs.number :id)}))
    (parser.anywhere
      (parser.tag :button {:type "*" :onclick "*" :class "*"} "Купить"))))

(fn normalize [product]
  (local year (parser.guess-year product.title))
  (local weight (number.string->number product.weight))
  (local price (number.string->number product.price))
  {:site "artoftea"
   :id product.id
   :title product.title
   :url product.url
   :description product.description
   :image product.image
   :year year
   :price price
   :weight weight
   :price-per (if (and price weight (< 0 weight))
                (/ (math.ceil (* (/ price weight) 10)) 10)
                nil)})

(fn products []
  (fetcher.from-html
    [{:path "redtea" :category "Красный чай"}
     {:path "greentea" :category "Зеленый чай"}]
    format-url
    product-peg
    normalize))

{: products}