1 files changed, 32 insertions, 0 deletions
diff --git a/vendor/html.fnl b/vendor/html.fnl
new file mode 100644
index 0000000..753bbb9
--- /dev/null
+++ b/vendor/html.fnl
@@ -0,0 +1,32 @@
+(local entity-replacements {"&" "&amp;" ; must be first!
+                            "<" "&lt;"
+                            ">" "&gt;"
+                            "\"" "&quot;"})
+
+(local entity-search
+       (.. "[" (table.concat (icollect [k (pairs entity-replacements)] k)) "]"))
+
+(fn escape [s]
+  (assert (= (type s) :string))
+  (s:gsub entity-search entity-replacements))
+
+(fn tag [tag-name attrs self-closing?]
+  (assert (= (type attrs) "table") (.. "Missing attrs table: " tag-name))
+  (let [attr-str (table.concat (icollect [k v (pairs attrs)]
+                                 (if (= v true) k
+                                     (.. k "=\"" (escape v)"\""))) " ")]
+    (.. "<" tag-name " " attr-str (if self-closing? " />" ">"))))
+
+(fn render [document allow-no-escape?]
+  (if (= (type document) :string)
+      (escape document)
+      (and allow-no-escape? (= (. document 1) :NO-ESCAPE))
+      (. document 2)
+      (let [[tag-name attrs & body] document
+            self-closing? (= 0 (# body))]
+        (.. (tag tag-name attrs self-closing?)
+            (table.concat (icollect [_ element (ipairs body)]
+                            (render element allow-no-escape?)) " ")
+            (if (not self-closing?) (.. "</" tag-name ">") "")))))
+
+{ :render render }